As one of the Stackoverflow posters says, and rightly, too, you have to account for the fact different cities can have the same name. To do so, you could make your second form field a 'select'.
A select field is two-dimensional. You could therefore design it to hold location IDs (select field value) and corresponding full distinguishing name (select field display text, for example, Paris France, Paris Kiribati, Paris Ontario, Paris Texas).
Below is a fully worked out example. It is based on your requirements, with employee first-names in place of location names. All you have to do is change the query and variable names to yours.
getEmployee.cfm
<cfif isDefined("form.firstName")>
<cfdump var="#form#">
</cfif>
<cfform name="empForm" id="empForm" action="#cgi.SCRIPT_NAME#">
<p>
Employee first name: <cfinput autosuggest="cfc:employee.getFirstname({cfautosuggestvalue})" autosuggestminlength="1" type="text" name="firstName" size="50" typeahead="yes">
</p>
<p>
Employee ID: <cfselect name="employeeID" bind="cfc:employee.getEmpID({firstName})" />
</p>
<p>
<cfinput type="submit" name="sbmt" value="Send">
</p>
</cfform>
Employee.cfc
<cfcomponent>
<cfset selected_emp_id = "">
<cffunction name="getFirstName" access="remote" output="false" returntype="array">
<cfargument name="suggestedValue" required="true" type="string">
<cfset var getEmpFirstName = queryNew("","")>
<cfset var fnameArray = arrayNew(1)>
<cfquery name = "getEmpFirstName" dataSource = "cfdocexamples">
SELECT FirstName
FROM Employees
</cfquery>
<cfloop query="getEmpFirstName">
<cfset fnameArray[currentrow]=FirstName>
</cfloop>
<cfreturn fnameArray>
</cffunction>
<cffunction name="getEmpID" access="remote" returntype="array">
<cfargument name="fName" required="true" type="string">
<cfset var getEmployee = queryNew("","")>
<cfset var empArray = arrayNew(2)>
<cfquery name = "getEmployee" dataSource = "cfdocexamples">
SELECT Emp_ID, FirstName || ' ' || LastName as empName
FROM Employees
WHERE FirstName = '#arguments.fName#'
</cfquery>
<!--- Values for the first - the default - select option --->
<cfset empArray[1][1]="">
<cfset empArray[1][2]="Select employee">
<cfloop query="GetEmployee">
<cfset empArray[currentrow+1][1]=Emp_ID>
<cfset empArray[currentrow+1][2]=empName>
</cfloop>
<!--- Alternative, if you require no "Select employee" option --->
<!--- <cfloop query="GetEmployee">
<cfset empArray[currentrow][1]=Emp_ID>
<cfset empArray[currentrow][2]=empName>
</cfloop> --->
<cfreturn empArray>
</cffunction>
</cfcomponent>
In any case, as other posters have already suggested, you should consider investing some time in alternative solutions to cfform. For example, JQuery form.